文化部通过鄂西南土家族苗族文化生态保护实验区总体规划

Question

I don't know Mathematica very well, I have an equation involving matrices of the following form: given two $5\times5$ matrices $A,B$ where $B$ is nilpotent we want to find a matrix $X$ such that

k X + B.X-X.B + A = 0

for an integer $k$.

Is there a command solving such an equation? I tried with Solve and LinearSolve, but it does not work.

Answer 1

You can use LyapunovSolve which solves a.x + x.b = c:

SeedRandom[1] ;
A = RandomReal[{-1, 1}, {5, 5}];
B = RandomReal[{-1, 1}, {5, 5}];
k = RandomReal[{-1, 1}];

a = k * IdentityMatrix[5] + B ;
b = - B ;
c = - A ;

LyapunovSolve[a,b,c]

Answer 2

This is a linear equation in X, so you can solve it, in principle by writing out the system matrix and the right-hand side like this:

A = RandomReal[{-1, 1}, {5, 5}];
B = RandomReal[{-1, 1}, {5, 5}];
k = RandomReal[{-1, 1}, {5, 5}];

X = Array[x, {5, 5}];
matrix = D[Flatten[k X + B . X - X . B], {Flatten[X], 1}];
rhs = Flatten[-A];
solution = ArrayReshape[LinearSolve[matrix, rhs], {5, 5}]

Of course, there might be way more clever solutions to this. E.g., we have not exploited, yet, that B is nilpotent. Probably you are supposed to multiply with B a couple of times from the left and from the right so that several terms cancel and the remainder can be used to eliminate some variables in the matrix X. Maybe the Jordan decomposition might be helpful.

Answer 3

Without using any matrix theory just straightly writing an equation.

A = RandomInteger[{-10, 10}, {5, 5}];
B = RandomInteger[{-10, 10}, {5, 5}];
k = RandomInteger[{-10, 10}];

(* solution *)
# /. Solve[k # + B . # - # . B + A == 0] &@Array[x, Dimensions[A]]

(* verification *)
k # + B . # - # . B + A & /@ %

---

{{{0, 0, 0, 0, 0}, {0, 0, 0, 0, 0}, {0, 0, 0, 0, 0}, 
{0, 0, 0, 0, 0}, {0, 0, 0, 0, 0}}}